home *** CD-ROM | disk | FTP | other *** search
/ The Arsenal Files 8 / The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO / g_quake / dropde-2.zip / SUBS.QC < prev    next >
Text File  |  1996-08-28  |  6KB  |  315 lines
  1. void() SUB_Null = {};
  2.  
  3. void() SUB_Remove = {remove(self);};
  4.  
  5.  
  6. /*
  7. QuakeEd only writes a single float for angles (bad idea), so up and down are
  8. just constant angles.
  9. */
  10. vector() SetMovedir =
  11. {
  12.     if (self.angles == '0 -1 0')
  13.         self.movedir = '0 0 1';
  14.     else if (self.angles == '0 -2 0')
  15.         self.movedir = '0 0 -1';
  16.     else
  17.     {
  18.         makevectors (self.angles);
  19.         self.movedir = v_forward;
  20.     }
  21.     
  22.     self.angles = '0 0 0';
  23. };
  24.  
  25. /*
  26. ================
  27. InitTrigger
  28. ================
  29. */
  30. void() InitTrigger =
  31. {
  32. // trigger angles are used for one-way touches.  An angle of 0 is assumed
  33. // to mean no restrictions, so use a yaw of 360 instead.
  34.     if (self.angles != '0 0 0')
  35.         SetMovedir ();
  36.     self.solid = SOLID_TRIGGER;
  37.     setmodel (self, self.model);    // set size and link into world
  38.     self.movetype = MOVETYPE_NONE;
  39.     self.modelindex = 0;
  40.     self.model = "";
  41. };
  42.  
  43. /*
  44. =============
  45. SUB_CalcMove
  46.  
  47. calculate self.velocity and self.nextthink to reach dest from
  48. self.origin traveling at speed
  49. ===============
  50. */
  51. void(entity ent, vector tdest, float tspeed, void() func) SUB_CalcMoveEnt =
  52. {
  53. local entity    stemp;
  54.     stemp = self;
  55.     self = ent;
  56.  
  57.     SUB_CalcMove (tdest, tspeed, func);
  58.     self = stemp;
  59. };
  60.  
  61. void(vector tdest, float tspeed, void() func) SUB_CalcMove =
  62. {
  63. local vector    vdestdelta;
  64. local float        len, traveltime;
  65.  
  66.     if (!tspeed)
  67.         objerror("No speed is defined!");
  68.  
  69.     self.think1 = func;
  70.     self.finaldest = tdest;
  71.     self.think = SUB_CalcMoveDone;
  72.  
  73.     if (tdest == self.origin)
  74.     {
  75.         self.velocity = '0 0 0';
  76.         self.nextthink = self.ltime + 0.1;
  77.         return;
  78.     }
  79.         
  80. // set destdelta to the vector needed to move
  81.     vdestdelta = tdest - self.origin;
  82.     
  83. // calculate length of vector
  84.     len = vlen (vdestdelta);
  85.     
  86. // divide by speed to get time to reach dest
  87.     traveltime = len / tspeed;
  88.  
  89.     if (traveltime < 0.1)
  90.     {
  91.         self.velocity = '0 0 0';
  92.         self.nextthink = self.ltime + 0.1;
  93.         return;
  94.     }
  95.     
  96. // set nextthink to trigger a think when dest is reached
  97.     self.nextthink = self.ltime + traveltime;
  98.  
  99. // scale the destdelta vector by the time spent traveling to get velocity
  100.     self.velocity = vdestdelta * (1/traveltime);    // qcc won't take vec/float    
  101. };
  102.  
  103. /*
  104. ============
  105. After moving, set origin to exact final destination
  106. ============
  107. */
  108. void()  SUB_CalcMoveDone =
  109. {
  110.     setorigin(self, self.finaldest);
  111.     self.velocity = '0 0 0';
  112.     self.nextthink = -1;
  113.     if (self.think1)
  114.         self.think1();
  115. };
  116.  
  117.  
  118. /*
  119. =============
  120. SUB_CalcAngleMove
  121.  
  122. calculate self.avelocity and self.nextthink to reach destangle from
  123. self.angles rotating 
  124.  
  125. The calling function should make sure self.think is valid
  126. ===============
  127. */
  128. void(entity ent, vector destangle, float tspeed, void() func) SUB_CalcAngleMoveEnt =
  129. {
  130. local entity        stemp;
  131.     stemp = self;
  132.     self = ent;
  133.     SUB_CalcAngleMove (destangle, tspeed, func);
  134.     self = stemp;
  135. };
  136.  
  137. void(vector destangle, float tspeed, void() func) SUB_CalcAngleMove =
  138. {
  139. local vector    destdelta;
  140. local float        len, traveltime;
  141.  
  142.     if (!tspeed)
  143.         objerror("No speed is defined!");
  144.         
  145. // set destdelta to the vector needed to move
  146.     destdelta = destangle - self.angles;
  147.     
  148. // calculate length of vector
  149.     len = vlen (destdelta);
  150.     
  151. // divide by speed to get time to reach dest
  152.     traveltime = len / tspeed;
  153.  
  154. // set nextthink to trigger a think when dest is reached
  155.     self.nextthink = self.ltime + traveltime;
  156.  
  157. // scale the destdelta vector by the time spent traveling to get velocity
  158.     self.avelocity = destdelta * (1 / traveltime);
  159.     
  160.     self.think1 = func;
  161.     self.finalangle = destangle;
  162.     self.think = SUB_CalcAngleMoveDone;
  163. };
  164.  
  165. /*
  166. ============
  167. After rotating, set angle to exact final angle
  168. ============
  169. */
  170. void() SUB_CalcAngleMoveDone =
  171. {
  172.     self.angles = self.finalangle;
  173.     self.avelocity = '0 0 0';
  174.     self.nextthink = -1;
  175.     if (self.think1)
  176.         self.think1();
  177. };
  178.  
  179.  
  180. //=============================================================================
  181.  
  182. void() DelayThink =
  183. {
  184.     activator = self.enemy;
  185.     SUB_UseTargets ();
  186.     remove(self);
  187. };
  188.  
  189. /*
  190. ==============================
  191. SUB_UseTargets
  192.  
  193. the global "activator" should be set to the entity that initiated the firing.
  194.  
  195. If self.delay is set, a DelayedUse entity will be created that will actually
  196. do the SUB_UseTargets after that many seconds have passed.
  197.  
  198. Centerprints any self.message to the activator.
  199.  
  200. Removes all entities with a targetname that match self.killtarget,
  201. and removes them, so some events can remove other triggers.
  202.  
  203. Search for (string)targetname in all entities that
  204. match (string)self.target and call their .use function
  205.  
  206. ==============================
  207. */
  208. void() SUB_UseTargets =
  209. {
  210.     local entity t, stemp, otemp, act;
  211.  
  212. //
  213. // check for a delay
  214. //
  215.     if (self.delay)
  216.     {
  217.     // create a temp object to fire at a later time
  218.         t = spawn();
  219.         t.classname = "DelayedUse";
  220.         t.nextthink = time + self.delay;
  221.         t.think = DelayThink;
  222.         t.enemy = activator;
  223.         t.message = self.message;
  224.         t.killtarget = self.killtarget;
  225.         t.target = self.target;
  226.         return;
  227.     }
  228.     
  229.     
  230. //
  231. // print the message
  232. //
  233.     if (activator.classname == "player" && self.message != "")
  234.     {
  235.         centerprint (activator, self.message);
  236.         if (!self.noise)
  237.             sound (activator, CHAN_VOICE, "misc/talk.wav", 1, ATTN_NORM);
  238.     }
  239.  
  240. //
  241. // kill the killtagets
  242. //
  243.     if (self.killtarget)
  244.     {
  245.         t = world;
  246.         do
  247.         {
  248.             t = find (t, targetname, self.killtarget);
  249.             if (!t)
  250.                 return;
  251.             remove (t);
  252.         } while ( 1 );
  253.     }
  254.     
  255. //
  256. // fire targets
  257. //
  258.     if (self.target)
  259.     {
  260.         act = activator;
  261.         t = world;
  262.         do
  263.         {
  264.             t = find (t, targetname, self.target);
  265.             if (!t)
  266.             {
  267.                 return;
  268.             }
  269.             stemp = self;
  270.             otemp = other;
  271.             self = t;
  272.             other = stemp;
  273.             if (self.use != SUB_Null)
  274.             {
  275.                 if (self.use)
  276.                     self.use ();
  277.             }
  278.             self = stemp;
  279.             other = otemp;
  280.             activator = act;
  281.         } while ( 1 );
  282.     }
  283.     
  284.  
  285. };
  286.  
  287.  
  288. /*
  289.  
  290. in nightmare mode, all attack_finished times become 0
  291. some monsters refire twice automatically
  292.  
  293. */
  294.  
  295. void(float normal) SUB_AttackFinished =
  296. {
  297.     self.cnt = 0;        // refire count for nightmare
  298.     if (skill != 3)
  299.         self.attack_finished = time + normal;
  300. };
  301.  
  302. float (entity targ) visible;
  303.  
  304. void (void() thinkst) SUB_CheckRefire =
  305. {
  306.     if (skill != 3)
  307.         return;
  308.     if (self.cnt == 1)
  309.         return;
  310.     if (!visible (self.enemy))
  311.         return;
  312.     self.cnt = 1;
  313.     self.think = thinkst;
  314. };
  315.